Jeoloji Müh.

Jeoloji Müh.

Jeoloji Müh.

Alıntı

---

ProhibiT :
Probleminiz şimdi anlaşıldı :)
Drawing dosyanıza Attach ettiğiniz Raster Image'in en-boy oranı (aspect Ratio) bozuk.
Aslında AutoCAD komutlarıyla Raster İmage'i edit ederek yapmak mümkün.
Aspect Ratio'yu düzelttikten sonra Move etmek yeterli.
Öyle 4 noktaya da gerek yok, 2 nokta ile her şey çözülür.
Bununla birlikte, pek çok arkadaşımızın işine yarayacağını düşünerek bir fonksiyon yazacağım.
Şu an biraz yoğunum, akşama yazıp paylaşmış olurum.
Takipte olun lütfen...

---

Alıntı

---

ProhibiT :
Matrix çarpımları için üşendim açıkçası :) bunun için 3 kez Transformation Matrix kullandım.

Kod:

;|===========================================================================|;
;| RsAL: Algining Raster Image to Real Coordinates                           |;
;| Seçilen Raster Image Objesi, 2 nokta seçilerek Align edilir.              |;
;| Image objesinin En/Boy oranı düzenlenir, gerçek koordinatına getirilir.   |;
;|          Hayırlayan: M. Şahin Güvercin - www.autocadokulu.com             |;
;|---------------------------------------------------------------------------|;
(defun c:RsAL (/ *error* Map p1 n1 p2 n2 VecX VecY)
  (setvar "cmdecho" 0) (command "_.undo" "group") (vl-load-com)
  (defun *error* (/ er) (princ (strcat "\n" er))
    (command "_.undo" "e") (setvar "cmdecho" 1) (prin1))
  (princ "\nKoordinatlarına getirilecek Raster Image...")
  (while (not (setq Map (ssget ":s" (list (cons 0 "Image"))))))
  (setq Map (ssname Map 0)
        p1 (getpoint "\nBirinci Noktayı tıklayarak seçiniz...")
        n1 (list (getreal "\nBirinci Nokta X koordinatı: ")
                 (getreal "\nBirinci Nokta Y koordinatı: ") 0.00)
        p2 (getpoint "\n İkinci Noktayı tıklayarak seçiniz...")
        n2 (list (getreal "\n İkinci Nokta X koordinatı: ")
                 (getreal "\n İkinci Nokta Y koordinatı: ") 0.00)
        VecX (/ (- (car n2) (car n1)) (- (car p2) (car p1)))
        VecY (/ (- (cadr n2) (cadr n1)) (- (cadr p2) (cadr p1))))
  (vla-transformby (vlax-ename->vla-object Map)
    (vlax-tmatrix (list (list 1 0 0 (- (car p1))) (list 0 1 0 (- (cadr p1)))
                        (list 0 0 1 0) (list 0 0 0 1))))
  (vla-transformby (vlax-ename->vla-object Map)
    (vlax-tmatrix (list (list VecX 0 0 0) (list 0 VecY 0 0)
                        (list 0 0 1 0) (list 0 0 0 1))))
  (vla-transformby (vlax-ename->vla-object Map)
    (vlax-tmatrix (list (list 1 0 0 (car n1)) (list 0 1 0 (cadr n1))
                        (list 0 0 1 0) (list 0 0 0 1))))
  (command "_.zoom" "Object" Map "")
  (command "_.undo" "e") (setvar "cmdecho" 1) (prin1))

Not: Seçilen iki nokta biribirine göre ortogonal (yatayda ya da düşeyde aynı hizada) olmamalıdır.

---