07.12.2011 17:25

66878    

Geçersiz link :(

03.09.2012 13:12

69872    

linki yenileyebilir miyiz?

20.11.2013 11:33

75145    

Sarmal Merdiven Lispi Kod;


;SPST.LSP
;Copyright 1995 Xue-dong Zhao
;
;Draw spiral stair
;
;--------------------------------------------------------------------
;Main function
;--------------------------------------------------------------------
(defun c:spst ( / zcmd zblp zosm cn ag0 r1 r2 ag ht rase
dag dht ag1 tyn ty rw rn rt p1 p2 p3 p4
pa pb b1 b2 b31 b41 b5 b6 b32 b42
plist lista listb nr
)
(setq zcmd (getvar "cmdecho")
zblp (getvar "blipmode")
zosm (getvar "osmode")
)
(setvar "cmdecho" 0)
(initget 1)
(setq cn (getpoint "\nMerkez:"))
(initget 1)
(setq ag0 (getangle cn "\nİlk Basamak Dönme Açısı:"))
(initget 7)
(setq r1 (getdist cn "\nİç Yarıçap:"))
(initget 7)
(setq r2 (getdist cn "\nDış Yarıçap:"))
(initget 3)
(setq ag (getreal "\nİlk ve Son Basamaklar Arası Açı:"))
(initget 3)
(setq ht (getreal "\nMerdiven Yüksekliği [+ up][- down]:"))
(initget 7)
(setq nr (getint "\nBasamak Sayısı:")
ag (* pi (/ ag 180.0))
rase (/ ht nr)
dag (/ ag nr)
dht (/ ht (1+ nr))
ag1 (- ag0 dag)
tyn 8
)
(setvar "osmode" 0)
(setvar "blipmode" 0)
(initget 1 "A B")
(setq ty (getkword "\nSarmal Merdiven Tipi<A><B>:"))
(initget 5)
(setq rw (getreal "\nKorkuluk Genişliği:"))
(initget 5)
(setq rh (getreal "\nKorkuluk Yüksekliği:"))
(initget 1)
(if (= ty "A")
(setq rt (* -1 (getreal "\nKorkuluk Kalınlığı:")) tyn 4)
)
(repeat (+ nr 1)
(setq ag1 (+ ag1 dag)
p1 (polar cn ag1 r1)
p2 (polar cn ag1 r2)
p3 (sp p1 dht)
p4 (sp p2 dht)
)
(if (minusp ht)
(setq pa (sp p1 (* 2 dht))
pb (sp p2 (* 2 dht))
)
(setq pa (sp p1 (* -1 dht))
pb (sp p2 (* -1 dht))
)
)
(if (and (equal ag1 ag0 0.001)(null (minusp ht)))
(setq pa p1 pb p2)
)
(if (and (equal ag1 (+ ag0 ag) 0.001)(minusp ht))
(setq pa (sp p1 dht)
pb (sp p2 dht)
))
(setq b1 (sp p1 rh)
b2 (polar b1 ag1 rw)
b31 (polar p1 ag1 rw)
b41 (polar cn ag1 (- r2 rw))
b5 (sp b41 rh)
b6 (polar b5 ag1 rw)
b32 (sp b31 dht)
b42 (sp b41 dht)
)
(if (= ty "A")
(setq plist (append plist (list pa p1 p2 pb pa p3 p4 pb))
lista (append lista (list b1 b2 (sp b2 rt)(sp b1 rt)))
listb (append listb (list b5 b6 (sp b6 rt)(sp b5 rt)))
)
)
(if (= ty "B")
(setq plist (append plist (list pa b1 b2 b31 b41 b5 b6 pb
pa b1 b2 b32 b42 b5 b6 pb))
)
)
(setq cn (list (car cn)(cadr cn)(+ (caddr cn) dht)))
)
(setq nr (length plist))
(command "3dmesh" (/ nr tyn) tyn)
(repeat nr
(command (car plist))
(setq plist (cdr plist))
)
(command "")
(spstnc)
(if lista
(progn (setq nr (length lista))
(command "3dmesh" (/ nr 4) "4")
(repeat nr (command (car lista))
(setq lista (cdr lista))
)
(command "")
(spstnc)
(command "3dmesh" (/ nr 4) "4")
(repeat nr (command (car listb))
(setq listb (cdr listb))
)
(command "")
(spstnc)
)
)
(setvar "osmode" zosm)
(setvar "blipmode" zblp)
(setvar "cmdecho" zcmd)
(princ)
)
;
;--------------------------------------------------------------------
;Get the point with increment h in Z direction
;--------------------------------------------------------------------
(defun sp ( pt h)
(list (car pt)(cadr pt)(+ (caddr pt) h))
)
;
;--------------------------------------------------------------------
;Enclose the 3D mesh as the last entity in N direction
;--------------------------------------------------------------------
(defun spstnc ( / en ed )
(setq en (entlast)
ed (entget en)
ed (subst (cons 70 48)(assoc 70 ed) ed)
)
(entmod ed)
)
;
;--------------------------------------------------------------------
;Print message
;--------------------------------------------------------------------
;
(princ "\nSPST.LSP loaded. Type SPST to draw spiral stair.")
(princ)

23.03.2017 14:22

84860    

link ölmüş :(