;;;============================================================================
;;;                     Hazırlayan: M. Şahin Güvercin                         
;;;                    www.autocadokulu.com 30-09-2011                         
;;;============================================================================
(defun c:bcv (/ bName angL sSeT L m pivot p0 insPt dangL p1 dx dy dz)
  (setvar "cmdecho" 0) (command "_.undo" "begin") (vl-load-com)
  (if (= (setq bName (getstring "\nBLock Name: ")) "")
    (setq bName (cdr (assoc 2 (entget (ssname (ssget ":s"
                                               (list (cons 0 "insert"))) 0)))))
    (if (not (tblsearch "bLock" bName))
      (progn (princ (strcat "\n" bName " isimli bLock bulunamadı!")) (exit))))
  (if (setq angL (getreal (strcat "\n" bName
                                " bLock'larının çevrileceği açıyı giriniz: ")))
    (setq angL (* (/ angL 180.0) pi))
    (setq angL (angle (setq p1 (getpoint "\nİlk noktayı seçiniz."))
                      (getpoint p1 "\nİkinci noktayı seçiniz."))))
  (princ "\nÇevrilecek Blockları seçiniz.")
  (setq sSeT (ssget (list (cons 0 "insert") (cons 2 bName)))
        L (sslength sSeT) m -1)
  (while (< (setq m (1+ m)) L)
    (setq pivot (entget (ssname sSeT m))
          p0    (vla-getboundingbox (vlax-ename->vla-object
                                      (ssname sSeT m)) 'mnp 'mxp)
          p0    (mapcar '(lambda (pr1 pr2) (/ (+ pr1 pr2) 2.0))
                        (vlax-safearray->list mnp) (vlax-safearray->list mxp))
          insPt (cdr (assoc 10 pivot)) dangL (- angL (cdr (assoc 50 pivot))))
    (vla-transformby (vlax-ename->vla-object (cdr (assoc -1 pivot)))
      (vlax-tmatrix (list
          (list (cos dangL) (- (sin dangL)) 0 (- (car insPt) (- (* (car insPt)
                                   (cos dangL)) (* (cadr insPt) (sin dangL)))))
          (list (sin dangL) (cos dangL) 0 (- (cadr insPt) (+ (* (car insPt)
                                   (sin dangL)) (* (cadr insPt) (cos dangL)))))
          (list 0 0 1 0) (list 0 0 0 1))))
    (setq p1 (vla-getboundingbox (vlax-ename->vla-object
                                   (ssname sSeT m)) 'mnp 'mxp)
          p1 (mapcar '(lambda (pr1 pr2) (/ (+ pr1 pr2) 2.0))
                     (vlax-safearray->list mnp) (vlax-safearray->list mxp))
          dx (- (car p0) (car p1)) dy (- (cadr p0) (cadr p1))
          dz (- (caddr p0) (caddr p1)))
    (vla-transformby (vlax-ename->vla-object (ssname sSeT m)) (vlax-tmatrix
        (list (list 1 0 0 dx) (list 0 1 0 dy) (list 0 0 1 0) (list 0 0 0 1)))))
  (command "_.undo" "e") (princ)
) (write-line "\nPrepared by: M. Şahin Güvercin - www.autocadokulu.com")(prin1)