;|***************************************************************************|
| KYA: Kiriş Yazılarını Ayırma                                              |
|      Kiriş Numarası ve Kiriş Boyutundan oluşan tek bir Text Nesnesi,      |
|      Numara ve Boyut kısımları ayrılarak iki Text nesnesi elde edilir.    |
|       M. Şahin Güvercin (ProhibiT) - www.cizimokulu.com - 25.06.2014      |
|---------------------------------------------------------------------------|;
(defun c:KYA  (/ Bip By ByT Kn KnO KnBy myerr n1 n2 n3 n4 olderr RfP Sip)
  (setvar "cmdecho" 0) (command "_.undo" "group") (vl-load-com)
  (defun myerr (errmsg /) (if (/= errmsg "Function cancelled") (prompt errmsg))
    (command-s "._undo" "_e") (command-s "._U") (setq *error* olderr) (princ))
  (setq olderr *error* *error* myerr)
  (while (setq KnO (ssget ":s" (list (cons 0 "Text"))))
    (setq KnO  (entget (ssname KnO 0)) KnBy (cdr (assoc 1 KnO)))
    (if (wcmatch KnBy "* *")
      (setq Bip  (cdr (assoc 10 KnO))
            RfP  (mapcar '(lambda (n1 n2) (+ n1 n2)) BiP
                         (mapcar '(lambda (n3 n4) (- n4 n3))
                           (nth 0 (textbox KnO)) (nth 1 (textbox KnO))))
            Kn   (substr KnBy 1 (vl-string-position 32 KnBy))
            By   (vl-string-right-trim ")" (vl-string-left-trim "("
                   (vl-string-left-trim " " (vl-string-left-trim Kn KnBy))))
            KnO  (subst (cons 1 Kn) (assoc 1 KnO) KnO)
            ByT  (subst (cons 1 By) (assoc 1 KnO) KnO)
            Sip  (mapcar '(lambda (n1 n2) (- n1 n2)) Rfp
                         (mapcar '(lambda (n3 n4) (- n4 n3))
                           (nth 0 (textbox ByT)) (nth 1 (textbox ByT))))
            ByT (entmake (subst (cons 10 Sip) (assoc 10 ByT) ByT))))
    (entmod KnO)) (command "_.undo" "end") (setq *error* olderr) (prin1))